Arduino návody: Měření AC proudu s Arduino UNO

// Mereni AC proudu s mericim transformatorem proudu 20A typ: CT-08CL10, 2000:1 
// se zobrazenim na LCD se seriovou komunikaci, pro mereni AC proudu / 230V AC. 
// www.mojeelektronika.mzf.cz  vagnervlastimil@seznam.cz

#include <SoftwareSerial.h>                    // pripojeni knihovny pro kmunikaci  LCD displejem
#define txPin 2                                // definovani komunikacniho pinu s lcd displejem klidova uroven na lcd je nastavena na "T" vysoka 
SoftwareSerial LCD = SoftwareSerial(0, txPin); // pripojeni nastavenych parametru ke knihovně
const int LCDdelay=300;                        // nastaveni casove prodlevy pro lcd displej
#define L1_pinTrafo A0                         // nastaveni cisla PINU pro pripojeni vystupu zatezoveho (snimaciho) rezistoru
int prevod = 2000;                             // prevodni pomer transformatoru
float odpor = 100.0;                           // hodnota zatezoveho (snimaciho) rezistoru
float L1_Spickovenapeti;                       // seznam mericich promennych 
float L1_Spickovyproud;                        // seznam mericich promennych 
float L1_proudRMSnaRezistoru;                  // seznam mericich promennych 
float L1_proudRMS;                             // seznam mericich promennych 
float L1_odberWatt;                            // seznam mericich promennych 
float L1_celkem;                               // seznam mericich promennych 

void setup(){
delay(1000);                                   // casova prodleva  
pinMode(L1_pinTrafo, INPUT);                   // nastaveni pinu s prevodnik transformatoreem jako vstup
pinMode(txPin, OUTPUT);                        // nastaveni komunikacniho pinu na vystup
LCD.begin(2400);                               // nastaveni prenosove rychlosti
smazLCD();                                     // prikaz pro inicializaci lcd a smazani displeje
podsviceniOn() ;                               // zapnuti podsviceni displeje
kursorOff();                                   // vypnuti kursoru blikani
posunvpravo();                                 // nastaveni posunu znaku vpravo  
}

void loop() {
L1_Spickovenapeti = L1_NapetiSpickaSpicka();                // ziskani napeti Spicka-spicka pomoci funkce 
L1_Spickovyproud = ((L1_Spickovenapeti / odpor) * 1000.0);  // vypocet proudu v mA tekoucjho rezistorem pomoci Ohmova zakona
L1_proudRMSnaRezistoru = (L1_Spickovyproud * 0.707);        // vypocet RMS hodnoty proudu
L1_proudRMS = (L1_proudRMSnaRezistoru * prevod);            // vypocet mereneho proudu diky znalosti prevodniho pomeru 2000:1
L1_odberWatt = 230.0 * (L1_proudRMS / 1000.0);              // zjednoduseny vypocet spotreby ve Wttech 230=sitove napeti
L1_celkem = (L1_proudRMS / 1000);                           // prepocet z honoty mA pro zobrazeni "A" 0.134A
LCDpoziceznaku(0,0); LCD.print("L1 A: ");                   // nastaveni pozice prvniho znaku na prvnim radku
delay(100);                                                 // casova prodleva pro zapis znaku
if (L1_proudRMS <= 0 ){                                     // porovnani hodnoty pokud je nizssi nebo rovna "0" pokracuje na dalsim radku
LCDpoziceznaku(0,6); LCD.print("          ");}              // vymazani znaku od pozice 0,6  
else{                                                       // pokud neni pravda pokracuje na dalsim radku
LCDpoziceznaku(0,6); LCD.print(L1_celkem,3);                // nastaveni pozice vypoctu na prvnim radku vysledek na tri desetinna mista
delay(100);}                                                // casova prodleva pro zapis znaku
LCDpoziceznaku(1,0); LCD.print("L1 W: ");                   // nastaveni pozice prvniho znaku na ctvrtem radku
delay(100);                                                 // casova prodleva pro zapis znaku
if (L1_odberWatt <= 0){                                     // porovnani hodnoty pokud je nizssi nebo rovna "0" pokracuje na dalsim radku
LCDpoziceznaku(1,6); LCD.print("          ");}              // vymazani znaku od pozice 0,6  
else{                                                       // pokud neni pravda pokracuje na dalsim radku
LCDpoziceznaku(1,6); LCD.print(L1_odberWatt,3);             // nastaveni pozice vypoctu na druhem radku vysledek na tri desetinna mista
delay(3000);}                                               // casova prodleva pred dalsim cteni proudu
}
float L1_NapetiSpickaSpicka(){                        
float L1_vysledek = 0;                                      // merici promenne
int L1_merenaHodnota = 0;                                   // merici promenne
int L1_maximum = 0;                                         // merici promenne
unsigned long zacatekMereni = millis();                     // ulozeni startovaciho casu
while ((millis() - zacatekMereni) < 1000){                  // mereni po dobu jedne sekundy 
L1_merenaHodnota = analogRead(L1_pinTrafo);                 // mereni napeti na odporu
if (L1_merenaHodnota > L1_maximum){                         // nalezeni maxima
L1_maximum = L1_merenaHodnota;                              // ulozeni noveho maxima
  }
 }
L1_vysledek = ((L1_maximum * 5.0) / 1024);                  // prevod vysledku na napeti ve Voltech
L1_vysledek = (L1_vysledek - 2.500);                        // vypocet hodnoty o stejnosmerne napeti prevodniku 2.500V
return L1_vysledek;                                         // vraceni vysledku funkce
}
//podprogramy pro nastaveni lcd displeje
void LCDpoziceznaku(int row, int col){                      // nastaveni pozice zobrazeni znaku
if(row>1){row -= 2;                                         // porovnani zda je row vetsi nez jedna
LCD.write(0xFE); LCD.write((col + row*64 + 148));}          // vypocet pozice znaku pro treti a ctvrty radek
else{LCD.write(0xFE);LCD.write((col + row*64 + 128));}      // vypocet pozice znaku pro prvni a druhy radek
delay(LCDdelay);}                                           // konec podporgramu
void smazLCD(){                                             // smazani a inicializace lcd displeje
LCD.write(0xFE); LCD.write(0x01); delay(LCDdelay);}         // prikaz pro smazani
void podsviceniOn(){                                        // zapnuti podsviceni lcd displeje 
LCD.write(0xFE); LCD.write(0xE9);  delay(LCDdelay);}        // prikaz pro zapnuti
void podsviceniOff(){                                       // vypnuti podsviceni lcd displeje
LCD.write(0xFE); LCD.write(0xE8);  delay(LCDdelay);}        // prikaz pro vypnuti podsviceni displeje
void kursorOn(){                                            // zapnuti kursoru podtrzitka blikani
LCD.write(0xFE); LCD.write(0x0E); delay(LCDdelay);}         // prikaz pro zapnuti kursoru zobrazeni
void kursorOff(){                                           // prikaz pro vypnuti zobrazeni kursoru
LCD.write(0xFE); LCD.write(0x0C); delay(LCDdelay);}         // prikaz pro vypnuti kursoru
void posunvpravo(){                                         // zapsane znaky se zapisuji zleva doprava
LCD.write(0xFE); LCD.write(0x06); delay(LCDdelay);}         // prikaz pro posun zapsanych znaku